AI for Instrumentation Engineers: Real Examples & Limits

This desk task is the best example I have of AI for instrumentation engineers in practice. When I was given three Excel sheets, the question sounded simple: what has changed in the current sheet compared to the other two?

The sheets came from three project phases, so the instruments, services and loops were the same. The only difference was a phase code inside every tag: 01, 02 and 03.

Most engineers would open VLOOKUP and compare sheet by sheet. But VLOOKUP says “No Match” for almost every tag, even when you can see the tags are the same instruments.

So I went down a different path. I asked Copilot for a smarter lookup formula that ignores the phase code and compares all three sheets at once. As a result, I saved a huge amount of time.

In this guide to AI for instrumentation engineers, I’ll show you how the formula works, where else I use AI, and the line I never cross.

01Context

AI for Instrumentation Engineers: Where It Actually Fits

Let’s look at what our desk work actually looks like. A big share of it isn’t engineering judgement but data handling: instrument indexes, datasheets, I/O lists, cable schedules, vendor comments, TBE tables and revision comparisons.

So that’s exactly where AI for instrumentation engineers earns its place. Not as an engineer, but as a very fast assistant that never gets tired of Excel.

Where AI fits in typical I&C desk work

Look at the last column, because it never changes. Whatever AI produces, the engineer whose name goes on the document still owns it.

02Worked example

Real Example: How Instrumentation Engineers Can Use AI in Excel

This example shows AI for instrumentation engineers at its most practical, because it has a real desk problem, a real formula and a result you can check.

The Problem: Same Tags, Different Phase Code

Here’s my three-sheet instrument index comparison, shown with simplified sample data so that you can follow it. The real sheets had far more tags and columns, but a few rows are enough to show the logic. Sheet P01 is the Phase 01 reference, while sheet P03 is the current one.

Sample data: the red row no longer exists in Phase 03.

Sample data: amber cells changed, while the blue row is new.

For you and me, 01-FT-1001 and 03-FT-1001 are the same feed gas flow transmitter. For VLOOKUP, however, they are two completely different text strings. VLOOKUP looks for an exact match of the full tag, so it returns #N/A for every row.

The formula isn’t wrong, but the lookup key is.

The Fix: Compare on the Base Tag, Not the Full Tag

The fix is simple when you see it. Strip the phase code from every tag, compare on what’s left, and then check each attribute column for changes.

1. 1Build a base tag: 03-FT-1001 becomes FT-1001.
2. 2Then find the same base tag in the reference sheet.
3. 3If it isn’t there, the tag is New
4. 4If it is there, compare every attribute column and list the ones that Changed
5. 5Finally, run the check the other way round to catch Deleted tags.

How to Ask Copilot for It

If you want a good formula from Copilot, describe your data the way you’d brief a new engineer: the sheet names, the column layout, one real example of the tag format and the exact output you want back.

A vague request like “compare my sheets” gets you a vague formula. In contrast, a specific brief gets you something you can actually use.

The Formula, Step by Step

Here’s the logic rebuilt on the sample sheets so you can follow every line. It goes in cell P03!F2, and then you fill it down.

=IF($A2 = "", "",
  LET(
    key,     TEXTAFTER($A2, "-"),
    refTags, TEXTAFTER(P01!$A$2:$A$500, "-", , , , ""),
    pos,     XMATCH(key, refTags),
    oldRow,  INDEX(P01!$B$2:$E$500, pos, 0),
    newRow,  $B2:$E2,
    headers, $B$1:$E$1,
    changed, TEXTJOIN(", ", TRUE, IF(oldRow <> newRow, headers, "")),
    IF(ISNA(pos), "NEW tag",
       IF(changed = "", "No change", "Changed: " & changed))
  )
)

What each line does:

• keyTEXTAFTER cuts everything up to the first hyphen, so 03-FT-1001 becomes FT-1001.
• refTagsThe same cut applies to the whole tag column of P01, while the empty last argument stops blank rows from throwing errors.
• posXMATCH finds the row of the base tag in P01, so no match means the tag is new.
• oldRow / newRowThese hold the attribute values (columns B to E) for that tag, so the two rows can be compared.
• changedIt compares the two rows column by column and then joins the header names of whatever differs.
• final IFIf the tag is missing, it returns “NEW tag”; otherwise it returns “No change” or “Changed:” plus the column names.

Comparison result on the sample data

Also, to compare against Phase 02, copy the formula into column G and replace P01 with P02. Now your current sheet shows both references side by side, and you can see at a glance whether a change happened between 01 and 02 or only in 03.

Don’t Forget Deleted Tags

Most people miss this one, because the formula above only looks at tags that exist in the current sheet. Still, a tag that disappeared between phases is a change too, and it often matters most for your I/O count and cable schedule.

If you put this in any empty cell on a summary sheet, it spills a list of every P01 tag that no longer exists in P03:

=LET(
  refTags, P01!$A$2:$A$500,
  refKeys, TEXTAFTER(refTags, "-", , , , ""),
  curKeys, TEXTAFTER(P03!$A$2:$A$500, "-", , , , ""),
  FILTER(refTags, (refKeys <> "") * ISNA(XMATCH(refKeys, curKeys)),
         "No deleted tags")
)

On the sample data, it returns 01-XV-1004 Deleted. The inlet shutdown valve is gone from Phase 03, and that’s exactly the kind of change you want flagged before someone asks about a missing DO channel.

Case 1 / Case 2 / Case 3: Where Your Phase Code Sits

Every project has its own tagging philosophy, so the base-tag line changes depending on where the phase code sits. Then swap the key and refTags lines to match your case.

Base-tag formula for each tag format, so pick the row that matches your project

If your tags have no separator at all (for example 01FT1001) and the phase code is always two digits at the start, =MID(A2,3,100) does the job.

No Excel 365? Use a Helper Column

If your company is still on an older Excel version, the same idea works with classic functions. In that case, add a helper column F in both sheets with the base tag:

=TRIM(MID(A2, FIND("-", A2) + 1, 100))

Then, in P03, check one attribute at a time. For example, this one checks the Range column (D):

=IF(ISNUMBER(MATCH(F2, P01!$F:$F, 0)),
    IF(D2 = INDEX(P01!$D:$D, MATCH(F2, P01!$F:$F, 0)), "Same", "Changed"),
    "NEW tag")

Check the Output Before You Trust It

Copilot gave me the formula, but it didn’t take over the responsibility. Before any comparison result leaves my desk, I reconcile the counts:

Reconciliation on the sample data, for example with COUNTIF(F2:F500,”Changed*”)

• Reconcile the counts, because the comparison isn’t finished until the numbers add up.
• Spot-check by hand, including a few rows of each result type.
• Plant a change on a copy of the sheet, then confirm the formula catches it.
• Check for duplicate base tags, because XMATCH only returns the first match if two tags reduce to the same base tag.

03The rule

The Case 1/2/3 AI Rule for Instrumentation Engineers

But the Excel story is the easy part. The real question every I&C engineer needs to answer is: where does AI stop? So here’s how I draw the line between what I give AI, what I verify and what I never delegate.

04Verification

How Instrumentation Engineers Should Check AI Output

Checking is what makes AI for instrumentation engineers safe to use, so treat AI output the way a lead engineer treats a new engineer’s first submission. Not with suspicion, but with a checklist:

1. Trace every number back to a source document, such as a spec, datasheet, process data or calculation.
2. Open the standard yourself when a requirement or clause gets quoted.
3. Test with a known answer, for example a case you have already solved by hand.
4. Check units at every step, especially in anything involving pressure, flow or temperature.
5. Ask for the assumptions, because “List every assumption you made” is one of the most useful follow-up questions.

05Confidentiality

What Never Goes Into a Public AI Tool

This part is not optional, because it’s the first rule of AI for instrumentation engineers on client projects: before you paste anything into an AI tool, think about whose data it is.

06Pitfalls

Common AI Mistakes Instrumentation Engineers Make

These are the mistakes I see most often when instrumentation engineers start using AI on Excel sheets and project documents.

07The big question

Will AI Replace Instrumentation Engineers?

If you search this question, you’ll find plenty of scary answers. Here’s my view from an EPC desk instead.

AI is already good at the data side of our job, such as comparing sheets, structuring tables and drafting text. That part of the work will shrink, and it should.

But AI can’t own the result. For safety instrumented systems, IEC 61511 asks for competent people and verified work, while every project also asks for an accountable engineer.

So my answer is no. AI won’t replace instrumentation engineers, but instrumentation engineers who use AI well will move faster than those who don’t. That’s the real promise of AI for instrumentation engineers: less time fighting data, more time on engineering.